/* --------------------------------------------------------------
   file: waisProfile.sas
   Example of a PROFILE analysis taken from Morrison, 3rd Ed,
   1990, p. 466

   The data are Weschler Adult Intelligence Scale scores for
   four subscales on a group of 37 elderly individuals with no
   senile factor diagnosed and 12 eldery individuals with a
   senile factor present
  --------------------------------------------------------------- */

DATA WAIS;
  IMPUT senile $ info simil arithmtc piccomp;
  LABEL senile = 'Senile Factor'
        info='Information'
        simil='Similarities'
        arithmtc='Arithmetic'
        piccomp='Picture Completion';
DATALINES;
Yes  9  5  10  8
Yes 10  0   6  2
Yes  8  9  11  1
Yes 13  7  14  9
Yes  4  0  4   0
Yes  4  0  6   0
Yes 11  9  9   8
Yes 5  3  3  6
Yes  9  7  8  6
Yes  7  2  6  4
Yes 12 10 14  3
Yes 13 12 11 10
 No  7  5  9  8
 No  8  8  5  6
 No 16 18 11  9
 No  8  3  7  9
 No  6  3 13  9
 No 11  8 10 10
 No 12  7  9  8
 No  8 11  9  3
 No 14 12 11  4
 No 13 13 13  6
 No 13  9  9  9
 No 13 10 15  7
 No 14 11 12  8
 No 15 11 11 10
 No 13 10 15  9
 No 10  5  8  6
 No 10  3  7  7
 No 17 13 13  7
 No 10  6 10  7
 No 10 10 15  8
 No 14  7 11  5
 No 16 11 12 11
 No 10  7 14  6
 No 10 10  9  6
 No 10  7 10 10
 No  7  6  5  9
 No 15 12 10  6
 No 17 15 15  8
 No 16 13 16  9
 No 13 10 17  8
 No 13 10 17 10
 No 19 12 16 10
 No 19 15 17 11
 No 13 10  7  8
 No 15 11 12  8
 No 16  9 11 11
 No 14 13 14  9
;

* --- first examine the correlations to see if MANOVA
      is even needed;
TITLE 'WAIS subscale scores on senile and nonsenile elderly';
PROC CORR DATA=wais;
	VAR info--piccomp;
RUN;

* --- inspection of the results shows that the four
	  cognitive measures are stongly corrlated. hence,
      a MANOVA is the most appropriate design;
PROC GLM DATA=wais;
   CLASS senile;
   MODEL info--piccomp=senile;
   * --- the MEANS statement will print out the means and
         standard deviations for the two groups. you should
         ALWAYS examine the means;
   MEANS senile;
   * --- analysis of overall profile level. the PRINTE option
         prints the error SSCP and correlation matrix. the
         MNAMES option just gives a name to the level
         variable;
   RUN;
   TITLE2 Profile Level;
   MANOVA H=senile 
          M = info + simil + arithmtc + piccomp
          MNAMES = level / PRINTE;
   RUN;
   * --- analysis of profile shape. note that we create THREE
		 "new" variables using the M option. the SUMMARY
		 option prints an individual analysis for each of these
		 three variables;
   TITLE2 Profile Shape;
   MANOVA H=senile
          M=info - simil,  simil - arithmtc,  arithmtc - piccomp
          MNAMES = diff2 diff3 diff4 / PRINTE SUMMARY;
   RUN;
QUIT;