/* --------------------------------------------------------------------
	FILE: sem.interest.sas

	DATA: Interest data

	PURPOSE: Introduce PROC CALIS. Compare these results to	those
		from the output from file multreg.interest.sas which
		perform a path analysis using PROC REG
   -------------------------------------------------------------------- */

* - NOTE: Set LIBNAME p7291 to the directory/folder containing the
	interest data set;
*LIBNAME p7291 '';

OPTIONS NOCENTER NODATE PAGENO=1;
TITLE1 'Path Analysis on the Interest Data set using PROC CALIS';

/* The COV option to PROC CALIS instructs CALIS to analyze the
      covariance matrix instead of the correlation matrix (the default).
      This will give us unstandardized as well as standardized
      results.
   The CORR option prints the covariance and correlation matrix.
   The RESIDUAL option prints the difference between the observed
      covariance matrix and the predicted covariance matrix.
*/
PROC CALIS DATA=p7291.interest COV CORR RESIDUAL;

/* the VAR statement gives the observed variables to be analyzed */
   VAR lawyer archtct educ vocab geometry;

/* LINEQS gives the LINear EQuationS. There should be a separate
   equation for each endogenous variable. Each equation should be
   separated by a comma and a semicolon should be placed after the
   last equation. The equations are all of the form:

                   Y  = b  X  + b  X  + ... b  X  + e
                    i    i1 1    i2 2        ip P    i

   The Ys and the Xs should be names of variables. The bs can be
   any name that you wish as long as it is not a variable name.
   The error term MUST start with an e. */
   LINEQS
          lawyer = ble educ + blv vocab + blg geometry + e_l,
         archtct = bae educ + bav vocab + bag geometry + e_a;

/* The STD statement gives names for the variances (not the
   standard deviations) of the exogenous variables */
   STD educ=v_edu, vocab=v_voc, geometry=v_geo, e_l=ve_l, e_a=ve_a;

/* The COV statement gives names for the covariances between
   the exogenous variables */
   COV educ vocab =cov_ev, educ geometry=cov_eg,
            vocab geometry = cov_vg, e_l e_a = c_elea ;
RUN;