/* --------------------------------------------------------------------
	File: profileGenotype.sas

	Purposes:
		(1) Profile Analysis using genotype data set performed by
			(a) contrast coded variables
			(b) CONTRAST statement with PROC GLM
   -------------------------------------------------------------------- */

OPTIONS NOCENTER NODATE PAGENO=1;

/* --- Create a new data set with the contrast codes
		NOTE: LIBNAME p7291 must be assigned         --- */
DATA temp; SET p7291.Genotype;
   IF genotype='AA' THEN DO;
        Linear=1; Quadratic=-1;
   END;
   ELSE IF genotype='Aa' THEN DO;
        Linear=0; Quadratic=2;
   END;
   ELSE DO;
        Linear=-1; Quadratic=-1;
   END;
RUN;


TITLE 'Profile Analysis: Using Precoded Variables';
PROC GLM DATA=temp;
	MODEL y1 y2 = linear quadratic;

	TITLE2 'Linear Effect:';
	TITLE3 'Overall MANOVA';
	MANOVA H=linear /PRINTE;
	RUN;

	TITLE3 'Profile Level';
	MANOVA H=linear M= y1 + y2 MNAMES=Profile_Level / PRINTE;
	RUN;

	TITLE3 'Profile Shape';
	MANOVA H=linear M= y1 - y2 MNAMES=Profile_Shape / PRINTE;
	RUN;

	title2 'Quadratic (Dominance) Effect:';
	TITLE3 'Overall MANOVA';
	MANOVA H=lquadratic /PRINTE;
	RUN;

	TITLE3 'Profile Level';
	MANOVA H=quadratic M= y1 + y2 MNAMES=Profile_Level / PRINTE;
	RUN;

	TITLE3 'Profile Shape';
	MANOVA H=quadratic M= y1 - y2 MNAMES=Profile_Shape / PRINTE;
	RUN;
QUIT;



TITLE Profile Analysis: Using the CONTRAST statement with PROC GLM;
PROC GLM DATA=temp;
	CLASS Genotype;
	MODEL Y1 Y2 = Genotype;
	CONTRAST 'Linear' Genotype -1 0 1;
	CONTRAST 'Quadratic' Genotype -1 2 -1;
	RUN;

	TITLE2 Overall MANOVA;
	MANOVA H=Genotype;
	RUN;

	TITLE2 Profile Level;
	MANOVA H=Genotype M= Y1 + Y2 MNAMES=Profile_Level;
	RUN;

	TITLE2 Profile Shape;
	MANOVA H=Genotype M= y1 - y2 MNAMES=Profile_Shape;
	RUN;
QUIT;