/* ------------------------------------------------------------------
	FILE: manova2.sas

	DATA: (see below)

	PURPOSE: MANOVA with two dependent variables
   ------------------------------------------------------------------- */

/* --------------------------------------------------------
   Example of MANOVA using data from Tatsuoka, 1988, p. 274.
   The design is a two by three factorial that compared
   two methods of teaching shorthand (method A and method B)
   under three conditions of distributed versus massed
   practice:
     C1 = 2 hours of instruction per day for 6 weeks
     C2 = 3 hours of instruction per day for 4 weeks
     C3 = 4 hours of instruction per day for 3 weeks
   The dependent variables were measures of speed (SPEED)
   and accuracy (ACCURACY) on a standardized shorthand test
   after the completion of instruction.
   -------------------------------------------------------- */

DATA shorthnd;
  INPUT method $ practice $ speed accuracy;
CARDS;
A C1 36 26
A C1 34 22
A C1 28 21
A C1 34 23
A C1 34 21
A C1 29 19
A C1 48 25
A C1 28 20
A C1 34 21
A C1 38 20

A C2 46 17
A C2 34 21
A C2 31 17
A C2 31 18
A C2 36 23
A C2 26 19
A C2 35 16
A C2 33 19
A C2 23 15
A C2 30 14

A C3 26 14
A C3 31 14
A C3 30 16
A C3 34 16
A C3 30 13
A C3 27 13
A C3 21 12
A C3 31 15
A C3 37 14
A C3 29 14

B C1 42 25
B C1 47 24
B C1 51 29
B C1 35 25
B C1 37 26
B C1 44 28
B C1 44 25
B C1 49 24
B C1 43 24
B C1 36 26

B C2 32 18
B C2 39 19
B C2 37 17
B C2 31 17
B C2 36 19
B C2 32 19
B C2 31 17
B C2 41 21
B C2 36 18
B C2 40 20

B C3 28 11
B C3 28 10
B C3 25 10
B C3 22 12
B C3 27 11
B C3 25 12
B C3 33 14
B C3 31 13
B C3 28 12
B C3 23 11
;
RUN;

/* first we want to test whether speed and accuracy are correlated */
TITLE 'Example of MANOVA: Methods of shorthand instruction';
PROC CORR;
  VAR speed accuracy;
RUN;

/*next we want to plot the means for the various groups.
  we can do this using proc chart to give a visual display
  use these commands only on a graphics terminal */
GOPTIONS FTEXT=CENTX HTEXT=2;
PROC GCHART;
  VBAR method   / SUMVAR=speed  TYPE=MEAN  GROUP=practice
                  ERRORBAR=BOTH;
RUN;
PROC GCHART;
  VBAR method   / SUMVAR=accuracy TYPE=MEAN  GROUP=practice
                  ERRORBAR=BOTH;
RUN;

/* next we do the MANOVA */
PROC GLM;
   CLASS method practice;
   MODEL speed accuracy = method practice method*practice;
/* set up a linear and quadratic contrast for practice */
   CONTRAST 'linear practice' practice -1 0 1;
   CONTRAST 'quadratic practice' practice -1 2 -1;
/* the following statement does the MANOVA. The PRINTH option
   requests that the hypothesis SSCP matrix be printed and the
   PRINTE options requests that the error SSCP matrix be
   printed */
   MANOVA H=method practice method*practice/ PRINTH PRINTE;
RUN;