/* ------------------------------------------------------
	FILE: loglin2.sas

	DATA: Professions, Sex, Preference in Novels
		from Tabachnick & Fidell, 3rd Ed. p. 244ff

	PURPOSE: Illustrate log linear analysis
   ------------------------------------------------------ */

OPTIONS NOCENTER NODATE PAGENO=1;
TITLE 'Log Linear Analysis of Reading Preferences';

DATA reading;
   LENGTH professn $14 sex novel $6;
   INPUT professn sex novel freq;
cards;
Administrators   Male SciFi  10
Administrators Female SciFi   5
Administrators   Male   Spy  30
Administrators Female   Spy  10
Belly_Dancers    Male SciFi   5
Belly_Dancers  Female SciFi  10
Belly_Dancers    Male   Spy   5
Belly_Dancers  Female   Spy  25
Politicians      Male SciFi  15
Politicians    Female SciFi  15
Politicians      Male   Spy  10
Politicians    Female   Spy  15
;

/* Marginal Frequencies */
TITLE2 Marginal Frequencies;
PROC FREQ DATA=reading;
   TABLES professn sex novel;
   WEIGHT freq;
RUN;

/* Three way contingency table */
TITLE2 Three way contingency table;
PROC FREQ DATA=reading;
   TABLES professn*sex*novel;
   WEIGHT freq;
RUN;

/* Catgorical Data Analysis */
TITLE2;
PROC CATMOD DATA=reading;
   WEIGHT freq;
   MODEL professn*sex*novel=_response_;
   LOGLIN professn | sex | novel / TITLE='Fully saturated model'; RUN;
   LOGLIN professn | sex | novel @2 / TITLE='Only two way interactions'; RUN;
   LOGLIN professn   sex   novel @2 / TITLE='Complete independence'; RUN;
RUN;
QUIT;